Using ColdFusion ORM and HQL, Part 1

Thu, 09 Sep 2010 08:48:00 -0700

Now that the Hibernate integration in ColdFusion 9 has been in use for a while, we're seeing an increasing number of questions on the CF-ORM mailing list. This isn't surprising, Hibernate is a vast topic in and of itself, and the CF documentation can really only scratch the surface. There are entire books just dedicated to using Hibernate (my personal favorite being Java Persistence with Hibernate). It's one thing to look at the documentation and understand the simple use cases, but quite another to actually get into real world application development with Hibernate. With this in mind, I'm going to be posting a few blog entries that explore using CF and Hibernate in some more complex scenarios. The end result will be a rudimentary blog application, and I'll post that code in the last blog entry on this topic. But before we get to that, I want to back up and look at how one might approach the design of this application. Here is a simple UML diagram of the domain model I want to create: Contrary to good OO design, I'm not focusing on the behavior of these objects at all due to the fact that this is specifically an ORM example. I am also making the following assumptions, which affected the way the associations were defined, and will drive some later decisions when it comes to loading the objects:

A BlogEntry will typically be associated with a few BlogCategories (between one and four, but maybe a few more)
A large number of BlogEntries (hundreds or thousands) can be associated with a BlogCategory
A low to moderate number of BlogComments can be associated with a BlogEntry (probably up to a few dozen unless the entry triggers an unusual number of comments)
Each entity should keep track of when it was created and who created it

With this in mind, the relationships are defined as follows:

One User can be associated with many Entities via the createdBy property
One BlogCategory can be associated with many BlogEntries
Many BlogComments can be associated with a BlogEntry
One BlogEntry can be associated with a BlogComment

Translated into code, the entities look like this:

js|
component displayname="Entity" output="false" mappedsuperclass="true" accessors="true"
{
	property name="id" fieldtype="id" type="numeric" ormtype="int" generator="native";
	property name="dateCreated" type="date" ormtype="timestamp";
	property name="createdBy" fieldtype="many-to-one" cfc="User" fkcolumn="createdBy";
}

js|
component displayname="User" extends="Entity" persistent="true"
		  output="false" accessors="true"
{
	property name="name" type="string" ormtype="string";
}

js|
component displayname="BlogEntry" extends="Entity" output="false" 
		  persistent="true" accessors="true"
{
	property name="title" type="string" ormtype="string";
	property name="content" type="string" ormtype="text";
	property name="categories" singularname="category" fieldtype="many-to-many" 
  		     cfc="BlogCategory" linktable="entry_category" 
  		     fkcolumn="entryId" inversejoincolumn="categoryId";
	property name="comments" singularname="comment" fieldtype="one-to-many"
  		     cfc="BlogComment" fkcolumn="entryId" 
  		     orderby="dateCreated ASC" inverse="true";
	
	BlogEntry function init()
	{
		variables.categories = [];
		variables.comments = [];
		return this;
	}	
}

js|
component displayname="BlogCategory" extends="Entity" output="false"
		  persistent="true" accessors="true"
{
	property name="name" type="string" ormtype="string";
}

js|
component displayname="BlogComment" extends="Entity" output="false"
		  persistent="true" accessors="true"
{
	property name="content" type="string" ormtype="text";
	property name="blogEntry" fieldtype="many-to-one" 
 	  	     fkcolumn="entryId" cfc="BlogEntry";  
}

As you can see, this is really a tiny amount of code when you consider everything that is going on under the hood. This gives me a solid basis for the application. I can create these objects, set properties and associations, and persist them to the database. But that's the easy part. I want to go further than the simple use cases. In the upcoming entries, I'll look at how to best handle the bi-directional association between BlogEntry and BlogComment, as well as how to automatically set the createdBy and dateUpdated properties in Entity. I'll also be taking an in-depth look at using HQL for filtering, sorting, and optimizing the way the objects are created to eliminate unnecessary database queries.

More on CF9 ORM Relationships

Mon, 21 Dec 2009 13:07:00 -0700

My entry late last week on association management methods prompted a number of comments. I was going to add another comment but this became quite long so instead I'm adding another blog entry. The point of my last post was to talk about bidirectional relationships, particularly a one-to-many/many-to-one between two entities. Hibernate (and, thus, the CF9 ORM) has the ability to specify an "inverse" attribute on your relationship. To better show why you usually want to do this, let's look at an example. [More]

Bidirectional Association Management in ColdFusion 9 ORM

Wed, 16 Dec 2009 10:36:00 -0700

And to follow up on my recent pledge to start blogging further about ORM, lets jump right into a recent topic. A thread on the CF-ORM mailing list brought up the topic of dealing with a bidirectional relationship. [More]

Brian Kotek: Inversion of Control - Object-Relational Mapping

Using ColdFusion ORM and HQL, Part 1

More on CF9 ORM Relationships

Bidirectional Association Management in ColdFusion 9 ORM